2013 год 1 тур

Требуется

В каркасной конфигурации разработать программу, которая анализирует текущие остатки спецодежды на складах и формирует отчет, содержащий две таблицы.

В первой таблице отображается текущее наличие запасов спецодежды на складах и определяется средняя цена для каждого наименования спецодежды.

***Запасы спецодежды на складах предприятия на 01.04.2012***

|  |  |  |  |  |  |  |  |
| --- | --- | --- | --- | --- | --- | --- | --- |
| **Спецодежда** | **Цена** | **1 склад** | | **2 склад** | | **3 склад** | |
| **Кол-во** | **Стоимость** | **Кол-во** | **Стоимость** | **Кол-во** | **Стоимость** |
| СО-01 | 450 | 30 | 13500 | 10 | 4200 | 20 | 9300 |
| СО-02 | 280 | 18 | 5040 | 50 | 14000 | 15 | 4200 |
| СО-03 | 320 | 85 | 27200 | 60 | 19200 | 18 | 5760 |
| СО-04 | 610 | 5 | 3050 | 20 | 12200 | 62 | 37820 |
| СО-05 | 550 | 64 | 35200 | 12 | 6600 | 5 | 2750 |
| ИТОГО: |  |  | 83990 |  | 56200 |  | 59830 |
| ИТОГО по предприятию: | | 200020 | | | | | |

Во второй таблице должен быть представлен вариант размещения всех имеющихся запасов спецодежды на двух сохраняемых складах с соблюдением вышеуказанного условия – обеспечение максимальной близости (или равенства) стоимостной оценки запасов на этих складах, рассчитанной по средневзвешенной цене.

***Предлагаемый вариант размещения спецодежды на двух складах***

|  |  |  |  |  |  |
| --- | --- | --- | --- | --- | --- |
| **Спецодежда** | **Цена** | **1 склад** | | **2 склад** | |
| **Кол-во** | **Стоимость** | **Кол-во** | **Стоимость** |
| СО-01 | 450 | 46 | 20700 | 14 | 6300 |
| СО-02 | 280 | 28 | 7840 | 55 | 154000 |
| СО-03 | 320 | 100 | 32000 | 63 | 20160 |
| СО-04 | 610 | 7 | 4270 | 80 | 48800 |
| СО-05 | 550 | 64 | 35200 | 17 | 9350 |
| ИТОГО: |  |  | 100010 |  | 100010 |

Решение

Задача разделяется на 2 части: первая – составить сводную таблицу текущих данных, для создания таблицы требуются следующие данные: спецодежда (материалы), цена за единицу материала, количество и стоимость материала, находящегося на каждом складе. У нас имеются все данные, кроме цены за единицу материала, как именно находить цену материала сказано в задаче – «Оценка материальных запасов производится по средневзвешенной цене, которая определяется отдельно для каждого материала по предприятию в целом». Следовательно, для получения цены каждого материала, мы можем использовать следующую формулу: Цена = (Общая сумма / Общее количество). Используем следующий запрос, для получения цен материалов:

ВЫБРАТЬ

ЖурналПроводокОстатки.Субконто1,

СУММА(ЖурналПроводокОстатки.СуммаОстаток) / СУММА(ЖурналПроводокОстатки.КоличествоОстаток) КАК Цена

ИЗ

РегистрБухгалтерии.ЖурналПроводок.Остатки КАК ЖурналПроводокОстатки

ГДЕ

ЖурналПроводокОстатки.Счет.Код = "10"

СГРУППИРОВАТЬ ПО

ЖурналПроводокОстатки.Субконто1

И так, теперь у нас имеются все данные, которые требуется отобразить в первой части задания.

Для выполнения второй части задачи – составить предлагаемый вариант размещения материалов, требуется больше чем запрос. Для размещения материалов используем следующий алгоритм: отсортируем материалы от самого дорогого к самому дешевому, далее будем отправлять по одной единице материала на склад, на каждой итерации меняя склад на тот, где сумма товаров будет минимальной. Получается, товары будут равномерно распределены по оставшимся складам.

Пример:

Материал 1, цена 500, количество 3

Материал 2, цена 300, количество 2

Материал 3, цена 100, количество 5

Материалы будут распределены на 2 склада следующим образом:

|  |  |  |  |  |
| --- | --- | --- | --- | --- |
| Итерация | Склад 1 | Сумма Склад 1 | Склад 2 | Сумма Склад 2 |
| 1 | Материал 1 (500) | 500 |  | 0 |
| 2 |  | 500 | Материал 1 (500) | 500 |
| 3 | Материал 1 (500) | 1000 |  | 500 |
| 4 |  | 1000 | Материал 2 (300) | 800 |
| 5 |  | 1000 | Материал 2 (300) | 1100 |
| 6 | Материал 3 (100) | 1100 |  | 1100 |
| 7 | Материал 3 (100) | 1200 |  | 1100 |
| 8 |  | 1200 | Материал 3 (100) | 1200 |
| 9 | Материал 3 (100) | 1300 |  | 1200 |
| 10 |  | 1300 | Материал 3 (100) | 1300 |

В результате мы получаем равную сумму материалов на обоих складах. Для реализации алгоритма нам необходимо получить: список материалов, отсортированный по ценам от большего к меньшему, содержащий следующую информацию: материал, цена, общее количество на предприятии. Используя эту информацию можно распределить материалы по складам приведенным выше алгоритмом. Псевдокод алгоритма:

Для каждого материал Цикл

Для каждой единицы материала Цикл

Склад = склад с наименьшей суммой материалов

Отправить единицу материала на Склад

Конец цикла

Конец цикла

Реализация

Процедура КнопкаСформироватьНажатие(Кнопка)

ТабДок = ЭлементыФормы.ПолеТабДок;

Макет = Отчеты.ЛиквидацияСклада.ПолучитьМакет("Макет");

ОбластьЗаголовок = Макет.ПолучитьОбласть("Заголовок");

ОбластьЗаголовокОсновное = Макет.ПолучитьОбласть("ЗаголовокОсновное");

ОбластьЗаголовокСклад = Макет.ПолучитьОбласть("ЗаголовокСклад");

ОбластьЗаголовокИтого = Макет.ПолучитьОбласть("ЗаголовокИтого");

ОбластьДанныеОсновное = Макет.ПолучитьОбласть("ДанныеОсновное");

ОбластьДанныеСклад = Макет.ПолучитьОбласть("ДанныеСклад");

ОбластьДанныеИтого = Макет.ПолучитьОбласть("ДанныеИтого");

ОбластьДанныеПоПредприятию = Макет.ПолучитьОбласть("ДанныеПоПредприятию");

ТабДок.Очистить();

Склады = Новый Массив;

Материалы = Новый Массив;

Остатки = Новый Массив;

ИтогСумма = 0;

ИтогСкладыСумма = Новый Соответствие;

// Получаем склады

Запрос = Новый Запрос;

Запрос.Текст =

"ВЫБРАТЬ

| Склады.Ссылка

|ИЗ

| Справочник.Склады КАК Склады";

Результат = Запрос.Выполнить();

Выборка = Результат.Выбрать();

Пока Выборка.Следующий() Цикл

ДанныеСклада = Новый Структура;

ДанныеСклада.Вставить("Ссылка",Выборка.Ссылка);

Склады.Добавить(ДанныеСклада);

КонецЦикла;

// Получаем средние цены на материалы

Запрос = Новый Запрос;

Запрос.Текст = "ВЫБРАТЬ

| ЖурналПроводокОстатки.Субконто1.Ссылка КАК Ссылка,

| СУММА(ЖурналПроводокОстатки.СуммаОстаток) / СУММА(ЖурналПроводокОстатки.КоличествоОстаток) КАК Цена

|ИЗ

| РегистрБухгалтерии.ЖурналПроводок.Остатки КАК ЖурналПроводокОстатки

|ГДЕ

| ЖурналПроводокОстатки.Счет.Код = ""10""

|

|СГРУППИРОВАТЬ ПО

| ЖурналПроводокОстатки.Субконто1,

| ЖурналПроводокОстатки.Субконто1.Ссылка

|

|УПОРЯДОЧИТЬ ПО

| Цена УБЫВ";

Результат = Запрос.Выполнить();

Выборка = Результат.Выбрать();

Пока Выборка.Следующий() Цикл

ДанныеМатериала = Новый Структура;

ДанныеМатериала.Вставить("Ссылка",Выборка.Ссылка);

ДанныеМатериала.Вставить("Цена",Выборка.Цена);

Материалы.Добавить(ДанныеМатериала);

КонецЦикла;

// Получаем текущие запасы

Запрос = Новый Запрос;

Запрос.Текст =

"ВЫБРАТЬ

| ЖурналПроводокОстатки.Субконто1 КАК Материал,

| ЖурналПроводокОстатки.Субконто2 КАК Склад,

| ЖурналПроводокОстатки.СуммаОстаток,

| ЖурналПроводокОстатки.КоличествоОстаток

|ИЗ

| РегистрБухгалтерии.ЖурналПроводок.Остатки(&КонецПериода, , , ) КАК ЖурналПроводокОстатки

|ГДЕ

| ЖурналПроводокОстатки.Счет.Код = ""10""

|

|УПОРЯДОЧИТЬ ПО

| ЖурналПроводокОстатки.Субконто1.Наименование,

| ЖурналПроводокОстатки.Субконто2.Код";

Запрос.УстановитьПараметр("КонецПериода",ОтчетОбъект.Дата);

Результат = Запрос.Выполнить();

Выборка = Результат.Выбрать();

Предыдущий = Неопределено;

ТекущиеДанные = Неопределено;

Пока Выборка.Следующий() Цикл

Если Выборка.Материал <> Предыдущий Тогда

Предыдущий = Выборка.Материал;

Если ТекущиеДанные <> Неопределено Тогда

Остатки.Добавить(ТекущиеДанные);

КонецЕсли;

ТекущиеДанные = Новый Структура;

ТекущиеДанные.Вставить("Материал",Выборка.Материал);

Для Каждого Материал из Материалы Цикл

Если Материал.Ссылка = Выборка.Материал.Ссылка Тогда

ТекущиеДанные.Вставить("Цена",Материал.Цена);

Прервать;

КонецЕсли;

КонецЦикла;

КонецЕсли;

Для Каждого Материал из Материалы Цикл

Если Материал.Ссылка = Выборка.Материал.Ссылка Тогда

Количество = Неопределено;

Если Не Материал.Свойство("Количество",Количество) Тогда

Количество = 0;

КонецЕсли;

Материал.Вставить("Количество",Количество + Выборка.КоличествоОстаток);

Прервать;

КонецЕсли;

КонецЦикла;

МатериалНаСкладе = Новый Структура;

МатериалНаСкладе.Вставить("Склад",Выборка.Склад);

МатериалНаСкладе.Вставить("Сумма",Выборка.СуммаОстаток);

МатериалНаСкладе.Вставить("Количество",Выборка.КоличествоОстаток);

МатериалСклады = Неопределено;

Если Не ТекущиеДанные.Свойство("Склады",МатериалСклады) Тогда

МатериалСклады = Новый Массив;

КонецЕсли;

МатериалСклады.Добавить(МатериалНаСкладе);

ТекущиеДанные.Вставить("Склады",МатериалСклады);

СкладСумма = ИтогСкладыСумма.Получить(Выборка.Склад.Ссылка);

Если СкладСумма = Неопределено Тогда

ИтогСкладыСумма.Вставить(Выборка.Склад.Ссылка,Выборка.СуммаОстаток);

Иначе

ИтогСкладыСумма.Вставить(Выборка.Склад.Ссылка,СкладСумма + Выборка.СуммаОстаток);

КонецЕсли;

ИтогСумма = ИтогСумма + Выборка.СуммаОстаток;

КонецЦикла;

Если ТекущиеДанные <> Неопределено Тогда

Остатки.Добавить(ТекущиеДанные);

КонецЕсли;

// Строим Документ

ОбластьЗаголовок.Параметры[0] = "Запасы спецодежды на складах предприятия на " + Дата;

ТабДок.Вывести(ОбластьЗаголовок);

ТабДок.Вывести(ОбластьЗаголовокОсновное);

Для Каждого Склад Из Склады Цикл

ОбластьЗаголовокСклад.Параметры[0] = Склад.Ссылка.Наименование;

ТабДок.Присоединить(ОбластьЗаголовокСклад);

КонецЦикла;

Для Каждого Остаток Из Остатки Цикл

ОбластьДанныеОсновное.Параметры[0] = Остаток.Материал;

ОбластьДанныеОсновное.Параметры[1] = Остаток.Цена;

ТабДок.Вывести(ОбластьДанныеОсновное);

МатериалСклады = Остаток.Склады;

Для Каждого МатериалСклад Из МатериалСклады Цикл

ОбластьДанныеСклад.Параметры[0] = МатериалСклад.Количество;

ОбластьДанныеСклад.Параметры[1] = МатериалСклад.Сумма;

ТабДок.Присоединить(ОбластьДанныеСклад);

КонецЦикла;

КонецЦикла;

ТабДок.Вывести(ОбластьЗаголовокИтого);

Для Каждого Склад Из Склады Цикл

ОбластьДанныеИтого.Параметры[0] = ИтогСкладыСумма.Получить(Склад.Ссылка);

ТабДок.Присоединить(ОбластьДанныеИтого);

КонецЦикла;

ОбластьДанныеПоПредприятию.Параметры[0] = ИтогСумма;

ТабДок.Вывести(ОбластьДанныеПоПредприятию);

// Инициализируем данные результата

МатериалыРезультат = Новый Массив();

ИтогСкладыСумма = Новый Соответствие;

Для Каждого Материал из Материалы Цикл

Данные = Новый Структура;

Данные.Вставить("Материал",Материал.Ссылка);

Данные.Вставить("Цена",Материал.Цена);

СкладыРезультат = Новый Массив();

Для Каждого Склад Из Склады Цикл

Если Склад.Ссылка <> ОтчетОбъект.ЛиквидируемыйСклад.Ссылка Тогда

ДанныеСклад = Новый Структура;

ДанныеСклад.Вставить("Склад",Склад.Ссылка);

ДанныеСклад.Вставить("Сумма",0);

СкладыРезультат.Добавить(ДанныеСклад);

КонецЕсли;

КонецЦикла;

ТекущийСклад = СкладыРезультат[0];

Пока Материал.Количество > 0 Цикл

Количество = 0;

Если Не ТекущийСклад.Свойство("Количество",Количество) Тогда

ТекущийСклад.Вставить("Количество",1);

Иначе

ТекущийСклад.Вставить("Количество",Количество + 1);

КонецЕсли;

Сумма = 0;

Если Не ТекущийСклад.Свойство("Сумма",Сумма) Тогда

ТекущийСклад.Вставить("Сумма",1);

Иначе

ТекущийСклад.Вставить("Сумма",Сумма + Материал.Цена);

КонецЕсли;

СкладСумма = ИтогСкладыСумма.Получить(ТекущийСклад.Склад.Ссылка);

Если СкладСумма = Неопределено Тогда

ИтогСкладыСумма.Вставить(ТекущийСклад.Склад.Ссылка,Материал.Цена);

Иначе

ИтогСкладыСумма.Вставить(ТекущийСклад.Склад.Ссылка,СкладСумма + Материал.Цена);

КонецЕсли;

Для Каждого Склад Из СкладыРезультат Цикл

Если Склад.Сумма < ТекущийСклад.Сумма Тогда

ТекущийСклад = Склад;

КонецЕсли;

КонецЦикла;

Материал.Количество = Материал.Количество - 1;

КонецЦикла;

Данные.Вставить("Склады",СкладыРезультат);

МатериалыРезультат.Добавить(Данные);

КонецЦикла;

// Строим Документ

ОбластьЗаголовок.Параметры[0] = "Предлагаемый вариант размещения спецодежды";

ТабДок.Вывести(ОбластьЗаголовок);

ТабДок.Вывести(ОбластьЗаголовокОсновное);

Для Каждого Склад Из Склады Цикл

Если Склад.Ссылка <> ОтчетОбъект.ЛиквидируемыйСклад.Ссылка Тогда

ОбластьЗаголовокСклад.Параметры[0] = Склад.Ссылка.Наименование;

ТабДок.Присоединить(ОбластьЗаголовокСклад);

КонецЕсли;

КонецЦикла;

Для Каждого Материал Из МатериалыРезультат Цикл

ОбластьДанныеОсновное.Параметры[0] = Материал.Материал;

ОбластьДанныеОсновное.Параметры[1] = Материал.Цена;

ТабДок.Вывести(ОбластьДанныеОсновное);

МатериалСклады = Материал.Склады;

Для Каждого МатериалСклад Из МатериалСклады Цикл

ОбластьДанныеСклад.Параметры[0] = МатериалСклад.Количество;

ОбластьДанныеСклад.Параметры[1] = МатериалСклад.Сумма;

ТабДок.Присоединить(ОбластьДанныеСклад);

КонецЦикла;

КонецЦикла;

ТабДок.Вывести(ОбластьЗаголовокИтого);

Для Каждого Склад Из Склады Цикл

Если Склад.Ссылка <> ОтчетОбъект.ЛиквидируемыйСклад.Ссылка Тогда

ОбластьДанныеИтого.Параметры[0] = ИтогСкладыСумма.Получить(Склад.Ссылка);

ТабДок.Присоединить(ОбластьДанныеИтого);

КонецЕсли;

КонецЦикла;

КонецПроцедуры

Автор: Михайлов Алексей

Пояснения к коду:

ТабДок = ЭлементыФормы.ПолеТабДок;

Макет = Отчеты.ЛиквидацияСклада.ПолучитьМакет("Макет");

ОбластьЗаголовок = Макет.ПолучитьОбласть("Заголовок");

ОбластьЗаголовокОсновное = Макет.ПолучитьОбласть("ЗаголовокОсновное");

ОбластьЗаголовокСклад = Макет.ПолучитьОбласть("ЗаголовокСклад");

ОбластьЗаголовокИтого = Макет.ПолучитьОбласть("ЗаголовокИтого");

ОбластьДанныеОсновное = Макет.ПолучитьОбласть("ДанныеОсновное");

ОбластьДанныеСклад = Макет.ПолучитьОбласть("ДанныеСклад");

ОбластьДанныеИтого = Макет.ПолучитьОбласть("ДанныеИтого");

ОбластьДанныеПоПредприятию = Макет.ПолучитьОбласть("ДанныеПоПредприятию");

ТабДок.Очистить();

В данном блоке получаем элемент формы в который будем выводить результат (Поле табличного документа), макет представления данных и все требуемые области макета, которые будут использованы для построения документа. Последним действием отчищаем элемент формы, чтобы удалить старые данные (при повторном запуске формировки отчета).

Склады = Новый Массив;

Материалы = Новый Массив;

Остатки = Новый Массив;

ИтогСумма = 0;

ИтогСкладыСумма = Новый Соответствие;

В данном блоке проводится инициализация мест хранения данных, склады – массив, содержащий структуры с полями (Ссылка), Материалы – массив, содержащий структуры с полями (Ссылка, Цена), Остатки – массив, содержащий структуры с полями (Материал, Цена, Склады), ИтогСумма – сумма всех материалов по предприятию, ИтогСкладыСумма – соответствие (Склад – сумма материалов на складе). Следует уточнить, что поле Склады, структуры Остатков тоже является массивом, который содержит структуры с полями (Склад,Количество,Сумма). Приведем данные в более понятной форме:

|  |  |  |  |  |  |  |
| --- | --- | --- | --- | --- | --- | --- |
| Элемент массива… | Данные | | | | | |
| Склады | Ссылка | | | | | |
| Склад 1 | | | | | |
| Материалы | Ссылка | | Цена | | | |
| СО-01 | | 500 | | | |
| Остатки | Материал | Цена | | Склады | | |
| СО-01 | 500 | | Склад 1 | 10 | 5000 |
| Склад 2 | 5 | 2500 |

Запрос = Новый Запрос;

Запрос.Текст =

"ВЫБРАТЬ

| Склады.Ссылка

|ИЗ

| Справочник.Склады КАК Склады";

Результат = Запрос.Выполнить();

Выборка = Результат.Выбрать();

Пока Выборка.Следующий() Цикл

ДанныеСклада = Новый Структура;

ДанныеСклада.Вставить("Ссылка",Выборка.Ссылка);

Склады.Добавить(ДанныеСклада);

КонецЦикла;

В данном блоке идет обращение к базе данных, для получения всех складов. После получения данных, результат записывается в массив Склады.

Запрос = Новый Запрос;

Запрос.Текст = "ВЫБРАТЬ

| ЖурналПроводокОстатки.Субконто1.Ссылка КАК Ссылка,

| СУММА(ЖурналПроводокОстатки.СуммаОстаток) / СУММА(ЖурналПроводокОстатки.КоличествоОстаток) КАК Цена

|ИЗ

| РегистрБухгалтерии.ЖурналПроводок.Остатки КАК ЖурналПроводокОстатки

|ГДЕ

| ЖурналПроводокОстатки.Счет.Код = ""10""

|

|СГРУППИРОВАТЬ ПО

| ЖурналПроводокОстатки.Субконто1,

| ЖурналПроводокОстатки.Субконто1.Ссылка

|

|УПОРЯДОЧИТЬ ПО

| Цена УБЫВ";

Результат = Запрос.Выполнить();

Выборка = Результат.Выбрать();

Пока Выборка.Следующий() Цикл

ДанныеМатериала = Новый Структура;

ДанныеМатериала.Вставить("Ссылка",Выборка.Ссылка);

ДанныеМатериала.Вставить("Цена",Выборка.Цена);

Материалы.Добавить(ДанныеМатериала);

КонецЦикла;

В данном блоке происходит обращение к базе данных для получения списка материалов, с получением средневзвешенной цены, по которой происходит сортировка от большего к меньшему. Для получения данных учитывается только счет с кодом 10. После получения данных они записываются в массив Материалы.

Запрос = Новый Запрос;

Запрос.Текст =

"ВЫБРАТЬ

| ЖурналПроводокОстатки.Субконто1 КАК Материал,

| ЖурналПроводокОстатки.Субконто2 КАК Склад,

| ЖурналПроводокОстатки.СуммаОстаток,

| ЖурналПроводокОстатки.КоличествоОстаток

|ИЗ

| РегистрБухгалтерии.ЖурналПроводок.Остатки(&КонецПериода, , , ) КАК ЖурналПроводокОстатки

|ГДЕ

| ЖурналПроводокОстатки.Счет.Код = ""10""

|

|УПОРЯДОЧИТЬ ПО

| ЖурналПроводокОстатки.Субконто1.Наименование,

| ЖурналПроводокОстатки.Субконто2.Код";

Запрос.УстановитьПараметр("КонецПериода",ОтчетОбъект.Дата);

Результат = Запрос.Выполнить();

Выборка = Результат.Выбрать();

Предыдущий = Неопределено;

ТекущиеДанные = Неопределено;

Пока Выборка.Следующий() Цикл

Если Выборка.Материал <> Предыдущий Тогда

Предыдущий = Выборка.Материал;

Если ТекущиеДанные <> Неопределено Тогда

Остатки.Добавить(ТекущиеДанные);

КонецЕсли;

ТекущиеДанные = Новый Структура;

ТекущиеДанные.Вставить("Материал",Выборка.Материал);

Для Каждого Материал из Материалы Цикл

Если Материал.Ссылка = Выборка.Материал.Ссылка Тогда

ТекущиеДанные.Вставить("Цена",Материал.Цена);

Прервать;

КонецЕсли;

КонецЦикла;

КонецЕсли;

Для Каждого Материал из Материалы Цикл

Если Материал.Ссылка = Выборка.Материал.Ссылка Тогда

Количество = Неопределено;

Если Не Материал.Свойство("Количество",Количество) Тогда

Количество = 0;

КонецЕсли;

Материал.Вставить("Количество",Количество + Выборка.КоличествоОстаток);

Прервать;

КонецЕсли;

КонецЦикла;

МатериалНаСкладе = Новый Структура;

МатериалНаСкладе.Вставить("Склад",Выборка.Склад);

МатериалНаСкладе.Вставить("Сумма",Выборка.СуммаОстаток);

МатериалНаСкладе.Вставить("Количество",Выборка.КоличествоОстаток);

МатериалСклады = Неопределено;

Если Не ТекущиеДанные.Свойство("Склады",МатериалСклады) Тогда

МатериалСклады = Новый Массив;

КонецЕсли;

МатериалСклады.Добавить(МатериалНаСкладе);

ТекущиеДанные.Вставить("Склады",МатериалСклады);

СкладСумма = ИтогСкладыСумма.Получить(Выборка.Склад.Ссылка);

Если СкладСумма = Неопределено Тогда

ИтогСкладыСумма.Вставить(Выборка.Склад.Ссылка,Выборка.СуммаОстаток);

Иначе

ИтогСкладыСумма.Вставить(Выборка.Склад.Ссылка,СкладСумма + Выборка.СуммаОстаток);

КонецЕсли;

ИтогСумма = ИтогСумма + Выборка.СуммаОстаток;

КонецЦикла;

Если ТекущиеДанные <> Неопределено Тогда

Остатки.Добавить(ТекущиеДанные);

КонецЕсли;

В данном блоке происходит получение остатков на складах из базы данных. Остатки получаются до указанной даты (параметр КонецПериода), работа проходит так же только со счетом 10. Данные упорядочиваются по материалу и коду склада. Сортировка по материалу необходима, для того чтобы несколько записей относящихся к одному материалу, но разным складам, можно было рассматривать вместе. После получения данных они записываются в массив Остатки. Так как несколько строк выборки относятся к одной записи массива, используется дополнительная переменная Предыдущий (для определения момента перехода к следующему материалу) и переменная ТекущиеДанные, для заполнения структуры текущего материала. За определение перехода к следующему материалу отвечает следующий код:

Если Выборка.Материал <> Предыдущий Тогда

Предыдущий = Выборка.Материал;

Если ТекущиеДанные <> Неопределено Тогда

Остатки.Добавить(ТекущиеДанные);

КонецЕсли;

ТекущиеДанные = Новый Структура;

ТекущиеДанные.Вставить("Материал",Выборка.Материал);

Для Каждого Материал из Материалы Цикл

Если Материал.Ссылка = Выборка.Материал.Ссылка Тогда

ТекущиеДанные.Вставить("Цена",Материал.Цена);

Прервать;

КонецЕсли;

КонецЦикла;

КонецЕсли;

Если текущий материал выборки не соответствует предыдущему, то предыдущим считается текущий материал выборки, а текущие данные (заполненная структура предыдущего материала) добавляются в массив Остатки. После этого создается новая структура ТекущиеДанные, в которой заполняется поле Материал из выборки, и Цена. Для Цены материал ищется в массиве Материалы, содержащим цены на материалы.

Для Каждого Материал из Материалы Цикл

Если Материал.Ссылка = Выборка.Материал.Ссылка Тогда

Количество = Неопределено;

Если Не Материал.Свойство("Количество",Количество) Тогда

Количество = 0;

КонецЕсли;

Материал.Вставить("Количество",Количество + Выборка.КоличествоОстаток);

Прервать;

КонецЕсли;

КонецЦикла;

В данной части происходит подсчет количества материалов (общее количество материалов на предприятии), для дальнейшего распределения по складам. Сначала находится элемент массива Материалы соответствующий материалу выборки, далее берется текущее количество материала со структуры (с учетом того, что поле «Количество» может отсутствовать в структуре) и выставляется новое количество материала (Старое + Количество из выборки).

МатериалНаСкладе = Новый Структура;

МатериалНаСкладе.Вставить("Склад",Выборка.Склад);

МатериалНаСкладе.Вставить("Сумма",Выборка.СуммаОстаток);

МатериалНаСкладе.Вставить("Количество",Выборка.КоличествоОстаток);

МатериалСклады = Неопределено;

Если Не ТекущиеДанные.Свойство("Склады",МатериалСклады) Тогда

МатериалСклады = Новый Массив;

КонецЕсли;

МатериалСклады.Добавить(МатериалНаСкладе);

ТекущиеДанные.Вставить("Склады",МатериалСклады);

В данной части кода составляется структура для добавления в поле Склады элемента массива Остатки. После заполнения структуры, она добавляется в массив складов (с учетом того, что поле «Склады» может отсутствовать в структуре). После изменения массива, поле Склады заменяется этим массивом.

СкладСумма = ИтогСкладыСумма.Получить(Выборка.Склад.Ссылка);

Если СкладСумма = Неопределено Тогда

ИтогСкладыСумма.Вставить(Выборка.Склад.Ссылка,Выборка.СуммаОстаток);

Иначе

ИтогСкладыСумма.Вставить(Выборка.Склад.Ссылка,СкладСумма + Выборка.СуммаОстаток);

КонецЕсли;

ИтогСумма = ИтогСумма + Выборка.СуммаОстаток;

Эта часть кода отвечает за подсчет суммы цен материалов на складах и общей суммы на всем предприятии.

Если ТекущиеДанные <> Неопределено Тогда

Остатки.Добавить(ТекущиеДанные);

КонецЕсли;

Данная часть, расположенная сразу после цикла, необходима для того, чтобы последний материал выборки был добавлен в массив (добавление остальных происходит при изменении материала в выборке).

ОбластьЗаголовок.Параметры[0] = "Запасы спецодежды на складах предприятия на " + Дата;

ТабДок.Вывести(ОбластьЗаголовок);

ТабДок.Вывести(ОбластьЗаголовокОсновное);

Для Каждого Склад Из Склады Цикл

ОбластьЗаголовокСклад.Параметры[0] = Склад.Ссылка.Наименование;

ТабДок.Присоединить(ОбластьЗаголовокСклад);

КонецЦикла;

Для Каждого Остаток Из Остатки Цикл

ОбластьДанныеОсновное.Параметры[0] = Остаток.Материал;

ОбластьДанныеОсновное.Параметры[1] = Остаток.Цена;

ТабДок.Вывести(ОбластьДанныеОсновное);

МатериалСклады = Остаток.Склады;

Для Каждого МатериалСклад Из МатериалСклады Цикл

ОбластьДанныеСклад.Параметры[0] = МатериалСклад.Количество;

ОбластьДанныеСклад.Параметры[1] = МатериалСклад.Сумма;

ТабДок.Присоединить(ОбластьДанныеСклад);

КонецЦикла;

КонецЦикла;

ТабДок.Вывести(ОбластьЗаголовокИтого);

Для Каждого Склад Из Склады Цикл

ОбластьДанныеИтого.Параметры[0] = ИтогСкладыСумма.Получить(Склад.Ссылка);

ТабДок.Присоединить(ОбластьДанныеИтого);

КонецЦикла;

ОбластьДанныеПоПредприятию.Параметры[0] = ИтогСумма;

ТабДок.Вывести(ОбластьДанныеПоПредприятию);

Данный блок отвечает за построение табличного документа. Сначала производится вывод заголовков и названий складов, далее выводится все остатки. В завершение выводятся итоги по складам и общий итог.

МатериалыРезультат = Новый Массив();

ИтогСкладыСумма = Новый Соответствие;

Для Каждого Материал из Материалы Цикл

Данные = Новый Структура;

Данные.Вставить("Материал",Материал.Ссылка);

Данные.Вставить("Цена",Материал.Цена);

СкладыРезультат = Новый Массив();

Для Каждого Склад Из Склады Цикл

Если Склад.Ссылка <> ОтчетОбъект.ЛиквидируемыйСклад.Ссылка Тогда

ДанныеСклад = Новый Структура;

ДанныеСклад.Вставить("Склад",Склад.Ссылка);

ДанныеСклад.Вставить("Сумма",0);

СкладыРезультат.Добавить(ДанныеСклад);

КонецЕсли;

КонецЦикла;

ТекущийСклад = СкладыРезультат[0];

Пока Материал.Количество > 0 Цикл

Количество = 0;

Если Не ТекущийСклад.Свойство("Количество",Количество) Тогда

ТекущийСклад.Вставить("Количество",1);

Иначе

ТекущийСклад.Вставить("Количество",Количество + 1);

КонецЕсли;

Сумма = 0;

Если Не ТекущийСклад.Свойство("Сумма",Сумма) Тогда

ТекущийСклад.Вставить("Сумма",1);

Иначе

ТекущийСклад.Вставить("Сумма",Сумма + Материал.Цена);

КонецЕсли;

СкладСумма = ИтогСкладыСумма.Получить(ТекущийСклад.Склад.Ссылка);

Если СкладСумма = Неопределено Тогда

ИтогСкладыСумма.Вставить(ТекущийСклад.Склад.Ссылка,Материал.Цена);

Иначе

ИтогСкладыСумма.Вставить(ТекущийСклад.Склад.Ссылка,СкладСумма + Материал.Цена);

КонецЕсли;

Для Каждого Склад Из СкладыРезультат Цикл

Если Склад.Сумма < ТекущийСклад.Сумма Тогда

ТекущийСклад = Склад;

КонецЕсли;

КонецЦикла;

Материал.Количество = Материал.Количество - 1;

КонецЦикла;

Данные.Вставить("Склады",СкладыРезультат);

МатериалыРезультат.Добавить(Данные);

КонецЦикла;

Данный блок – главный, тут реализован алгоритм распределения материалов по оставшимся складам. Так как массив Материалы отсортирован от большего к меньшему по цене, мы обходим все элементы данного массива. На каждой итерации заполняется структура Данные для добавления в массив МатериалыРезультат, в структуру данные заполняются Материал,Цена и формируются массив Склады. Для распределения по складам составляется массив остающихся складов – СкладыРезультат (все склады кроме ликвидируемого). Далее материалы по единице распределяются по складам, выбирая склад с наименьшей суммой.

ОбластьЗаголовок.Параметры[0] = "Предлагаемый вариант размещения спецодежды";

ТабДок.Вывести(ОбластьЗаголовок);

ТабДок.Вывести(ОбластьЗаголовокОсновное);

Для Каждого Склад Из Склады Цикл

Если Склад.Ссылка <> ОтчетОбъект.ЛиквидируемыйСклад.Ссылка Тогда

ОбластьЗаголовокСклад.Параметры[0] = Склад.Ссылка.Наименование;

ТабДок.Присоединить(ОбластьЗаголовокСклад);

КонецЕсли;

КонецЦикла;

Для Каждого Материал Из МатериалыРезультат Цикл

ОбластьДанныеОсновное.Параметры[0] = Материал.Материал;

ОбластьДанныеОсновное.Параметры[1] = Материал.Цена;

ТабДок.Вывести(ОбластьДанныеОсновное);

МатериалСклады = Материал.Склады;

Для Каждого МатериалСклад Из МатериалСклады Цикл

ОбластьДанныеСклад.Параметры[0] = МатериалСклад.Количество;

ОбластьДанныеСклад.Параметры[1] = МатериалСклад.Сумма;

ТабДок.Присоединить(ОбластьДанныеСклад);

КонецЦикла;

КонецЦикла;

ТабДок.Вывести(ОбластьЗаголовокИтого);

Для Каждого Склад Из Склады Цикл

Если Склад.Ссылка <> ОтчетОбъект.ЛиквидируемыйСклад.Ссылка Тогда

ОбластьДанныеИтого.Параметры[0] = ИтогСкладыСумма.Получить(Склад.Ссылка);

ТабДок.Присоединить(ОбластьДанныеИтого);

КонецЕсли;

КонецЦикла;

Последняя часть процедуры – добавление в табличный документ данных распределения по складам. Вывод идет аналогично выводу остатков, но данные берутся из МатериалыРезультат, и в складах не учитывается ликвидируемый склад.

Сформированный отчет

